Blog: Heat-set threaded insert tooling box lid: box-cover.scad

/* The box the tips came in was 3D printed on an FDM printer.
 */

// All units are in inches.

fitting_gap = 0.01;

box_size = [
    1.400,
    1.750,
    0.315,
];
box_wall_thickness = 0.060;

lid_wall_thickness = box_wall_thickness;
cavity_size = [
    box_size.x + 2*fitting_gap,
    box_size.y + 2*fitting_gap,
    box_size.z,
];

overall_size = [
    cavity_size.x + 2*lid_wall_thickness,
    cavity_size.y + 2*lid_wall_thickness,
    cavity_size.z + lid_wall_thickness,
];

finger_grip_dia = .75;
cut_margin = 0.0001;

module lid() {
    difference() {
        cube(overall_size);
        translate([lid_wall_thickness, lid_wall_thickness, -cut_margin]) {
            cube([cavity_size.x,
                cavity_size.y,
                cavity_size.z+cut_margin]);
        }

        // Cut out places to grab the bottom of the box
        translate([overall_size.x/2, -cut_margin, cavity_size.z-finger_grip_dia/2]) {
            rotate([-90, 0, 0]) {
                cylinder(d=finger_grip_dia, h=overall_size.y+2*cut_margin, $fn=64);
            }
        }
    }
}

// Position the part on its back for printing purposes
translate([0, overall_size.y, overall_size.z]) {
    rotate([180, 0, 0]) {
        lid();
    }
}